#--------------------------------------------------------------------
# gnuplot script to plot speedstats.txt into speedtouch.png
# -IAN! idallen@idallen.ca www.idallen.com
#--------------------------------------------------------------------

# output format is PNG file
# write into speedtouch.png
# scale factor
#
set terminal png
set output "speedtouch.png"
set size 1.5,1.5

# use grid lines
#
set grid
set title "Minute-by-minute graphed output of selected data from 'adsl info' command on Speedtouch 516v6"
set xlabel "Date and Time - Year MM/DD HH:MM"

# input format is time
# output format is also time
#
set timefmt "%Y-%m-%d %H:%M:%S"
set xdata time
set format x "%Y\n%m/%d\n%H:%M"

# plot the data and limit the maximum Y values
# turn missing data into RED impulses
#
plot [] [0:13.5] \
     "speedstats.txt" using 2:(valid(23)?1/0:0.5) t "RED means line is down; modem can't keep synch:" with impulses \
    ,"speedstats.txt" using 2:($48) t "Downstream Margin [db]:" with points \
    ,"speedstats.txt" using 2:($75/1000) t "Downstream Cells/1000:" with points \
    ,"speedstats.txt" using 2:($76/1000) t "Downstream Kbit/s/1000:" with points ;