CST 8152 - Parsing - The Toy Language

This Toy Language contains the Toy Grammar for an assignment statement, plus the Print and Dump statements. We incorporate all three statement types into a new root non-terminal called <statement>:

<statement> -->
   ( <print> | <dump> | <assignment> ) ';'

<print> -->
   "print" <expression> ( ',' <expression> )*

<dump> -->
   "dump" ( <expression> ( ',' <expression> )* )?

<assignment> -->
   ID ‘=‘ <expression>

<expression> -->
   <term> ( ('+'|'-') <term> )*

<term> -->
   <factor> ( ('*'|'/') <factor> )*

<factor> -->
   ID | INT | STRING | '(' <expression> ')' | '-' <factor>

• The Toy Language grammar has 14 terminals:
  ID, INT, STRING, "print", "dump",
  (, ), +, -, *, /, ;, =, ','
• The Toy Language grammar has seven non-terminals:
  <statement>, <print>, <dump>,
  <assignment>, <expression>, <term>, <factor>
• Because of the distinct look-ahead sets for each of the statements in the language, the current input token uniquely determines which of the language statements we must be parsing, with no ambiguity. No backtracking will be needed to parse statements in this language.
• The "print" and "dump" tokens are reserved words in this grammar that begin the Print and Dump statements.
• The <factor> non-terminal contains a unary minus production that negates the value of its expression.